-- исходный ответ удален --
Основываясь на вашем комментарии к моему первоначальному ответу, теперь подразумевается, что Category_ID является внешним ключом, возможно, в таблице соединений, который не может (по какой-либо причине) быть включен в первоначальный запрос на отображение - или что вы просто хотите включить в сетку динамическую переменную, которая будет включена во время встроенных вставок без вмешательства пользователя (т. е. физически запретить им самим выбирать Category_ID, но что она по-прежнему будет динамической в некотором качестве, скажем... при подаче из URL var).
Если правильно, я считаю, что истинный вопрос ближе к:
Может ли CFGRID обновить несколько таблиц/динамических столбцов с помощью CFGRIDUPDATE?
Краткий ответ: Нет
Длинный ответ: Да, но не через CFGRIDUPDATE, а через CFQUERY и еще немного работы над CFGRID, через привязки CFC и CFAJAXPROXY.
Решение:
1) Вам понадобятся два файла для этого решения. Файл № 1 — это ваш компонент, который включает в себя функциональность запроса; мы назовем это cfgrid.cfc
<cfcomponent>
<cfset this.dsn = "gridexample" />
<cffunction name="getUsers" returntype="any" access="remote" output="false">
<cfargument name="page" />
<cfargument name="pageSize" />
<cfargument name="gridsortcolumn" />
<cfargument name="gridsortdirection" />
<cfset var getUsers = 0 />
<cfquery name="getUsers" datasource="#this.dsn#">
SELECT Users.UserID, Users.FirstName, UserCategories.Category_ID
FROM Users
INNER JOIN UserCategories ON (Users.User_ID = UserCategories.UserID)
<cfif arguments.gridsortcolumn neq "" or arguments.gridsortdirection neq "">
order by #arguments.gridsortcolumn# #arguments.gridsortdirection#
</cfif>
</cfquery>
<cfreturn QueryConvertForGrid(getUsers, page, pageSize) />
</cffunction>
<cffunction name="addNewUser" returntype="string" access="remote" output="false">
<cfargument name="fullname" type="string" required="true" />
<cfargument name="category_id" type="numeric" required="true" />
<cfquery datasource="#this.dsn#">
INSERT INTO Users
(
fullname
)
VALUES
(
<cfqueryparam cfsqltype="cf_sql_varchar" value="#arguments.fullname#">
)
</cfquery>
<cfquery name="getPkey" datasource="#this.dsn#">
SELECT Max(User_ID) as PKey
FROM Users
</cfquery>
<cfquery datasource="#this.dsn#">
INSERT INTO UserCategories
(
User_ID,
Category_ID
)
VALUES
(
<cfqueryparam cfsqltype="cf_sql_integer" value="#getPKey.PKey#" />
<cfqueryparam cfsqltype="cf_sql_integer" value="#arguments.category_id#" />
)
</cfquery>
<cfreturn "User Added" />
</cffunction>
<cffunction name="editUser" access="remote">
<cfargument name="gridaction">
<cfargument name="gridrow">
<cfargument name="gridchanged">
</cffunction>
</cfcomponent>
Обратите внимание на следующие ключевые части CFC:
а) getUsers() возвращает данные текущего пользователя вместе с его идентификатором категории. Вам придется переписать этот запрос, чтобы он соответствовал вашей схеме, но ключевой вывод заключается в том, что это запрос заполнения данных, поэтому все данные, необходимые для создания пользователя, также должны присутствовать для обновления пользователя. Это также предполагает, что у вас есть только 1 CategoryID для каждого пользователя (который многие разработчики денормализуют, оставляя CategoryID в таблице Users — я оставлю это на ваше усмотрение).
b) addNewUser() ожидает, что отправка формы/сетки будет проходить по новому имени, а также по category_id, но мы знаем заранее, что не будем просить, чтобы Category_ID заполнялся человеком ввод данных формы/сетки — мы сделаем это программно. Однако конечный результат остается тем же — запрос должен знать оба значения. Для краткости я отказался от <CFTRANSACTION>
вызовов, но имейте в виду, что вы собираетесь последовательно выполнить три запроса, один из которых (третий) зависит от динамических данных другого (первого и второго)- - поэтому вам нужно помнить о параллелизме, когда вы продвигаетесь вперед с этим типом дизайна.
c) На данный момент не обращайте внимания на editUser() - вам нужно будет заполнить его в какой-то момент - он просто должен существовать, чтобы эта демонстрация работала.
2) Второй файл, который вам понадобится, это внешний интерфейс — сама сетка, мы назовем ее cfgrid.cfm.
Мы пройдемся по этому, сверху вниз, так как он довольно большой, и каждый фрагмент кода потребует объяснения:
<cfparam name="URL.Category_ID" default=4 />
Первая строка шаблона параметрирует переменную URL, которую мы хотим использовать для программного обеспечения скрытого назначения новым пользователям. Используйте свой собственный механизм для предоставления динамического идентификатора Category_ID по мере необходимости.
<cfajaxproxy cfc="cfgrid" jsclassname="dataproxy">
Эта строка заставляет ColdFusion создать объект javascript с именем «dataproxy» и поместить его в контейнер, необходимый для обеспечения доступа к основным функциям, существующим в CFC, на который вы указываете... и в этом случае вы указываете на «cfgrid». ', который является нашим первым файлом, упомянутым выше (cfgrid.cfc). Таким образом, теперь вы можете спокойно ожидать, что у вас есть объект javascript с методами getUsers() и addNewUser().
<html>
<head>
<script type="text/javascript" src="/CFIDE/scripts/ajax/ext/package/toolbar/toolbar.js"></script>
Здесь вы начинаете теги HTML-документа и включаете ссылку на одну из библиотек Ajax, включенных в ColdFusion, файл toolbar.js.
<script type="text/javascript">
var dataproxy = new dataproxy();
dataproxy.setCallbackHandler(handleResult);
function handleResult(response)
{
alert(response);
}
Здесь вы создаете локальный экземпляр объекта dataproxy (помните выше, из вызова <CFAJAXPROXY>
) и назначаете обработчик обратного вызова, который указывает на другую функцию javascript 'handleResult'. Это процесс, который вы используете при работе с асинхронным взаимодействием — основной частью работы в Аякс.
function init()
{
grid = ColdFusion.Grid.getGridObject("UserGrid");
var gridHead = grid.getView().getHeaderPanel(true);
var tbar = new Ext.Toolbar(gridHead);
tbar.addButton({text:"Add User", handler:onAdd });
}
Эта функция init() создает объекты javascript, необходимые для связи с cfgrid. Вы получаете ссылку на cfgrid через ColdFusion.Grid.getGridObject и оттуда получаете доступ к заголовку сетки, что позволяет вам ориентироваться на панель инструментов, и добавляете кнопку «Добавить пользователя», которую затем программно решаете вызвать новую функцию при нажатии... эта функция называется "onAdd"...
function onAdd(button,event)
{
ColdFusion.Window.show('addUserWin');
}
Неудивительно, что вот эта функция onAdd(), которая отображает новое окно для добавления пользователя (это окно, содержащее поле ввода для полного имени пользователя).
Наконец, новому окну AddUserWin, показанному выше, потребуется собственная функция для добавления пользователя, так как нам нужно будет предоставить Category_ID динамически, а не позволить пользователю предоставить его. Итак, addUser() сделает именно это:
function addUser()
{
var f = document.frmUser;
dataproxy.addNewUser(
f.txtFullname.value,
f.txtCategory_ID.value
);
ColdFusion.Window.hide('addUserWin');
grid.refresh();
}
</script>
</head>
В addUser() мы обращаемся к <FORM>
ниже по его имени (frmUser) и вызываем метод addNewUser() нашего прокси-объекта javascript, который сопоставляется с CFC. Как и ожидалось, ему нужно знать значения нового пользователя, поэтому мы передадим ему значение txtFullname и txtCategory_ID. Мы заканчиваем, скрывая окно и обновляя сетку.
Помните, что теперь мы асинхронны, поэтому нам не нужно считывать результат и отображать его — этот результат сработает через обработчик обратного вызова, назначенный выше в методе handleResult().
Теперь создайте аргументы, которые будут кормить население CFGRID
:
<cfset args = StructNew() />
<cfset args.name = "UserGrid" />
<cfset args.format = "html" />
<cfset args.bindOnLoad = "true" />
<cfset args.bind = "cfc:cfgrid.getUsers({cfgridpage},{cfgridpagesize},{cfgridsortcolumn},{cfgridsortdirection})" />
<cfset args.selectmode = "edit" />
<cfset args.onchange = "cfc:cfgrid.editUser({cfgridaction},{cfgridrow},{cfgridchanged})" />
Здесь мы: 1. Назовем сетку «UserGrid» (так как мы назвали ее по этому имени в javascript выше), 2. Заставим ее отображать с помощью html, 3. Скажем, чтобы она привязывала свои данные при загрузке страницы, 4. Привязываем эти данные через cfgrid.cfc, вызывая метод getUsers() (и передавая текущие параметры cfgrid через значения страницы, размера страницы, столбца сортировки и направления сортировки), 5. Сделать его редактируемым и 6. Назначить обработчик onChange , если мы также хотим разрешить редактирование пользователей. Эта последняя часть (к сожалению) необходима, поэтому я не смог вырезать ее для этого примера.
Теперь постройте <CFFORM>
и <CFGRID>
:
<cfform>
<cfgrid attributeCollection="#args#">
<cfgridcolumn name="User_ID" display="false">
<cfgridcolumn name="Category_ID" display="false">
<cfgridcolumn name="FullName" header="Full Name">
</cfgrid>
</cfform>
Здесь мы заполняем сетку нашими аргументами, указанными выше, и вы заметите, что мы отображаем в сетке только поле «FullName», но User_ID и Category_ID все еще присутствуют и являются частью набора данных; они просто не отображаются в интерфейсе.
И последнее, но не менее важное: всплывающее окно, когда пользователь нажимает кнопку «Добавить нового пользователя», которое предоставляет интерфейс, необходимый для входа пользователя, и в то же время контролирует (за кулисами), что такое Category_ID. динамически поставляемый:
<cfwindow name="addUserWin" modal="true" resizable="false" title="Add New User">
<form name="frmUser">
<input type="hidden" name="txtCategory_ID" value="<cfoutput>#URL.Category_ID#</cfoutput>" />
<table width="100%">
<tr>
<td>Fullname</td>
<td><input type="text" name="txtFullname" value=""></td>
</tr>
<tr>
<td colspan="2"><input type="button" value="Add User" onclick="javascript:addUser();"></td>
</tr>
</form>
</cfwindow>
Этот вызов CFWINDOW обеспечивает необходимое «всплывающее окно» для инкапсуляции формы. Обратите внимание, что имя формы — frmUser, как мы упоминали выше в коде. Также обратите внимание, что имена полей совпадают (включая их регистр) с именами, указанными в javascript. Эта форма отображает поле Fullname для заполнения пользователем, в то время как Category_ID остается скрытым, но по-прежнему программно управляется вами — через ваш параметр URL в верхней части этого примера кода. Наконец, кнопка при нажатии запускает метод addUser(), который, как вы помните, обращается к объекту javascript, который, в свою очередь, взаимодействует с CFC и передает ваши данные в базу данных.
Наконец, непосредственно перед тем, как вы закончите этот шаблон, не забудьте запустить вашу функцию javascript init()!
<cfset ajaxOnLoad("init")>
</html>
Надеюсь это поможет.
Адаптировано из CRUD в формате cfgrid html ( Источник: Анудж Гахар)
07.12.2011