Использование пользовательского интерфейса jQuery в букмарклете

Я подозреваю, что проблема в том, что вы загружаете пользовательский интерфейс jQuery асинхронно. Линия

window.document.body.appendChild(s2)

начинает загрузку пользовательского интерфейса jQuery, но ваш код продолжает работу до того, как пользовательский интерфейс jQuery обязательно будет загружен. Это объясняет, почему вызов tabs() в вашем коде завершается неудачно, но успешно выполняется, когда вы выполняете его из консоли, после того как скрипт успел загрузиться.

Вы должны быть в состоянии исправить это, запустив остальную часть кода из обратного вызова.

s2.onreadystatechange = ->
  return unless @readyState is 'complete'
  # the rest of the code goes here

Редактировать: И если на то пошло, вы действительно должны сделать то же самое с s1, иначе вызов $ -> может завершиться ошибкой. Тот факт, что это удается, предполагает, что либо у вас есть кешированный jQuery в вашем браузере, либо на странице уже есть jQuery. Вы также должны использовать noConflict, чтобы избежать перезаписи существующей версии jQuery страницы. букмарклет Run jQuery Code, на который ссылается Acorn делает все это (и более кроссбраузерно, чем код в этом ответе).

Это должно работать:

((window, document, requirements, callback) ->
    getScript = (url, callback) ->
        script = document.createElement('script')
        script.src = url
        head = document.documentElement.childNodes[0]
        done = false
        script.onload = script.onreadystatechange = ->
          if not done and (not (readyState = @readyState) or readyState == 'loaded' or readyState == 'complete')
            done = true
            callback()
            script.onload = script.onreadystatechange = null
            head.removeChild script

        head.appendChild script

    if not ($ = window.jQuery) or requirements['jq'] > $.fn.jquery
        getScript 'http://ajax.googleapis.com/ajax/libs/jquery/1.6.1/jquery.js', ->
            getScript 'http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.7/jquery-ui.js', ->
                callback window.jQuery.noConflict(1)
    else
        if not (jqui_version = window.jQuery.ui.version) or requirements['jqui'] > jqui_version
            getScript 'http://ajax.googleapis.com/ajax/libs/jqueryui/1.8.7/jquery-ui.js', ->
                callback window.jQuery.noConflict(1)
        else
            callback window.jQuery.noConflict(1)

) window, document, {jq: '1.6.1', jqui: '1.8.7'}, ($) ->
    # Your code goes here:
    alert "jq: #{$.fn.jquery}, jqui: #{$.ui.version}"

Необходимо снять флажок "Добавить jQuery" на странице CoffeeMarklet, если вы используете приведенный выше код

Обновление: добавлена ​​проверка наличия jQuery и пользовательского интерфейса jQuery, чтобы он не загружался без необходимости.

Хотя это можно было бы улучшить, проверив, присутствует ли уже правильная версия jQuery, как это делает код Бена Алманса.

Атрибуция:

Бейги дал прекрасный фрагмент для загрузки ресурсов javascript один после другого.