Указатель Fortran на цель массива параметров

Атрибуты parameter и target действительно конфликтуют. Объект с атрибутом target должен быть переменной (Fortran 2018 8.5.17, C861); именованная константа (объект с атрибутом parameter) не является переменной (F2018, 8.5.13, C850).

Чтобы использовать целевые массивы, вы должны использовать переменные. Сложно иметь переменную, которая «безопасна» от изменения ее значения из-за ошибки программирования или чего-то подобного. Есть несколько соображений, которые запрещают появление переменной в контексте определения переменной. Если вы можете устроить такое состояние, то у компилятора есть шанс обнаружить вашу ошибку. Может ли это произойти легко?

Вне чистой процедуры и фиктивного аргумента intent(in) наиболее заманчивым запретом является защищенная переменная модуля:

module pars
  real, save, target, protected :: para1(74) = [...]
  real, save, target, protected :: para2(1) = [6]
end module

subroutine sub (...)
  use pars
  real, pointer :: p
  p => para1
end subroutine sub

Будучи защищенными, значения защищены от изменения вне модуля pars? Увы, даже если бы это было правдой, это бесполезно: будучи защищенными, мы не можем даже указать указатель на переменные модуля.

Таким образом, вашему компилятору будет нелегко обнаружить ошибку программирования, которая изменяет целевой массив переменной, поэтому, если вы хотите использовать массив в качестве цели, вам придется быть осторожным.

Следуя предложению @ja72 в комментарии, это попытка использовать один 2D-массив для параметров. Это прекрасно работает с gfortran-8.2 (на MacOS10.11).

program main
    implicit none
    integer i
    integer, parameter :: para1(*) = [1, 2, 3, 4, 5]
    integer, parameter :: para2(*) = [6, 7]
    integer, parameter :: N1 = size(para1), N2 = size(para2), N = max(N1, N2)
    integer, parameter :: params(N, 2) = &
            reshape( [ para1, (0, i = 1, N - N1), &
                       para2, (0, i = 1, N - N2) ], [N, 2] )

    print *, "para1 = ", params( :, 1 )
    print *, "para2 = ", params( :, 2 )

    print *, "Input i"
    read *, i
    print *, params( :, i )
end

$ gfortran-8 test.f90 && ./a.out

 para1 =            1           2           3           4           5
 para2 =            6           7           0           0           0
 Input i
1
           1           2           3           4           5

Однако, поскольку код становится немного сложным (из-за изменения формы) и может не работать со старыми компиляторами, может быть проще просто использовать массивы без параметров...