Как установить глобальную переменную VBA в одном проекте и использовать в другом проекте?

Вы можете добавить ссылку на внешнюю базу данных в вашу базу данных VCS.

Как? См. этот ответ.

Убедитесь, что имена модулей и функций в двух базах данных не конфликтуют. Затем вы можете просто сослаться на свою константу, используя MyModule.APP_TABLES_TO_BACKUP, или, если у вас есть несколько проектов с одним и тем же модулем и именем константы, MyProject.MyModule.APP_TABLES_TO_BACKUP

Поскольку мой предыдущий пост, по-видимому, не пришел пару дней назад...

Немного поискав, я наткнулся на пользовательские свойства базы данных Пола Мюррея, которые прекрасно работают.

С некоторыми изменениями я создал модуль, который включает общие методы добавления и удаления свойств.

' ---------------------------------
' FUNCTION:     AddDbProperty
' Description:  add custom properties to a database application
' ---------------------------------
Public Function AddDbProperty(DbProperty As String, _
                    DbPropertyValue As String, _
                    Optional DbPropertyType As Long = DB_TEXT, _
                    Optional DbFilename As String = "Current")
On Error GoTo Err_Handler

    Dim db As DAO.Database
    Dim prop As Property

    If DbFilename = "Current" Then
        Set db = DBEngine(0)(0)
    Else
        Set db = OpenDatabase(DbFilename)
    End If

    'add the property
    Set prop = db.CreateProperty(DbProperty, DbPropertyType, DbPropertyValue)
    db.Properties.Append prop

Exit_Handler:
    db.Close
    Set db = Nothing
    Exit Function

Err_Handler:
    Select Case Err.Number
      Case Else
        MsgBox "Error #" & Err.Number & ": " & Err.description, vbCritical, _
            "Error encountered (#" & Err.Number & " - AddDbProperty[mod_Dev_Properties])"
    End Select
    Resume Exit_Handler
End Function

' ---------------------------------
' FUNCTION:     RemoveDbProperty
' Description:  remove custom properties from a database applciation
' ---------------------------------
Public Function RemoveDbProperty(DbProperty As String, _
                    Optional DbFilename As String = "Current")
On Error GoTo Err_Handler

    Dim db As DAO.Database

    If DbFilename = "Current" Then
        Set db = DBEngine(0)(0)
    Else
        Set db = OpenDatabase(DbFilename)
    End If

    'remove the property
    db.Properties.Delete DbProperty

Exit_Handler:
    db.Close
    Set db = Nothing
    Exit Function

Err_Handler:
    Select Case Err.Number
      Case Else
        MsgBox "Error #" & Err.Number & ": " & Err.description, vbCritical, _
            "Error encountered (#" & Err.Number & " - RemoveDbProperty[mod_Dev_Properties])"
    End Select
    Resume Exit_Handler
End Function

' ---------------------------------
' FUNCTION:     UpdateDbProperty
' Description:  add custom properties to a database application
' ---------------------------------
Public Function UpdateDbProperty(DbProperty As String, _
                    DbPropertyValue As String, _
                    Optional DbFilename As String = "Current")
On Error GoTo Err_Handler

    Dim db As DAO.Database

    If DbFilename = "Current" Then
        Set db = DBEngine(0)(0)
    Else
        Set db = OpenDatabase(DbFilename)
    End If

    'add the property
    db.Properties(DbProperty) = DbPropertyValue

Exit_Handler:
    db.Close
    Set db = Nothing
    Exit Function

Err_Handler:
    Select Case Err.Number
      Case Else
        MsgBox "Error #" & Err.Number & ": " & Err.description, vbCritical, _
            "Error encountered (#" & Err.Number & " - UpdateDbProperty[mod_Dev_Properties])"
    End Select
    Resume Exit_Handler
End Function

С помощью немедленных свойств окна IDE можно добавлять/обновлять/удалять.

Например:

?AddDbProperty("My Property Name","My Property value")

Получение свойства легко выполняется через vba

CurrentDb.Properties("My Property Name")

Спасибо всем за также жизнеспособные входы!