Триггер SQL Server для вставки, обновления, удаления данных в другую таблицу на основе изменений в другой таблице

Вам нужно будет решить, обновлять или вставлять - в зависимости от введенных значений. Затем в вашем триггере у вас должны быть два отдельных оператора - один для вставки (как вы уже сделали), а другой для обновления.

Что-то вроде этого:

CREATE TRIGGER ContactsTrigger 
ON [dbo].[tblData]
FOR UPDATE
AS
    IF ....... (you need to somehow decide whether to update or insert here) ......
    BEGIN
        INSERT INTO dbo.Contacts (LastName, FirstName, MiddleName,     
                                  EmailAddress, HomePhone, MobilePhone, 
                                  Address, City, StateProvince, ZIPPostal, 
                                  id, ContactIDType)
            SELECT
                LastName, FirstName, MiddleName, 
                EmailAddress, HomePhone, MobilePhone, 
                Address, City, StateProvince, ZipPostal, 
                ID, ContactIDType
            FROM 
                INSERTED
    END
    ELSE BEGIN
        UPDATE dbo.Contacts
        SET LastName = i.LastName, FirstName = i.FirstName, 
            MiddleName = i.MiddleName, EmailAddress = i.EMailAddress, 
            HomePhone = i.HomePhone, MobilePhone = i.MobilePhone, 
            Address = i.Address, City = i.City, 
            StateProvince = i.StateProvince, ZipPostal = i.ZipPostal, 
            ContactIDType = i.ContactIDType
        FROM
            Inserted i            
        WHERE 
            -- define some condition that links the rows in the `Inserted` pseudo table 
            -- with the `Contacts` table - I just **guessed** it might be the `ID` column
            ID = I.ID  


    END
GO

Итак, сейчас ваша задача - выяснить, какое условие вы можете проверить, чтобы узнать, является ли строка новой и должна ли она быть вставлена ​​или обновлена.

• Может быть, значение ID уже существует в Contacts?
• Может быть, комбинация имени и фамилии? Другие колонки?

ОБНОВЛЕНИЕ: если ваш столбец ID является решающим фактором, попробуйте следующее: сначала он обновляет все те строки в dbo.Contacts, которые уже есть в таблице, а затем вставляет те, которые не являются частью dbo.Contacts:

CREATE TRIGGER ContactsTrigger 
ON [dbo].[tblData]
FOR UPDATE
AS
    -- first update existing rows in dbo.Contacts with values from "Inserted"...
    UPDATE dbo.Contacts
    SET LastName = i.LastName, FirstName = i.FirstName, 
        MiddleName = i.MiddleName, EmailAddress = i.EMailAddress, 
        HomePhone = i.HomePhone, MobilePhone = i.MobilePhone, 
        Address = i.Address, City = i.City, 
        StateProvince = i.StateProvince, ZipPostal = i.ZipPostal, 
        ContactIDType = i.ContactIDType
    FROM
        Inserted i            
    WHERE 
        -- define some condition that links the rows in the `Inserted` pseudo table 
        -- with the `Contacts` table - I just **guessed** it might be the `ID` column
        ID = I.ID  

    -- then secondly insert new rows into dbo.Contacts 
    INSERT INTO dbo.Contacts (LastName, FirstName, MiddleName,     
                              EmailAddress, HomePhone, MobilePhone, 
                              Address, City, StateProvince, ZIPPostal, 
                              id, ContactIDType)
        SELECT
            LastName, FirstName, MiddleName, 
            EmailAddress, HomePhone, MobilePhone, 
            Address, City, StateProvince, ZipPostal, 
            ID, ContactIDType
        FROM 
            INSERTED i
        WHERE
            i.ID NOT IN (SELECT ID FROM dbo.Contacts);

GO