Как сделать запись из последовательности значений

Внимание: работает только для буквальных последовательностей! (см. комментарий Михала)

Попробуйте этот макрос:

(defmacro instantiate [klass values] 
        `(new ~klass ~@values))

Если вы расширите его с помощью:

(macroexpand '(instantiate User ["John" "[email protected]" "Dreamland"]))

вы получите это:

(new User "John" "[email protected]" "Dreamland")

что в принципе вам и нужно.

И вы можете использовать его для создания экземпляров других типов записей или классов Java. По сути, это просто конструктор класса, который принимает одну последовательность параметров вместо множества параметров.

функция derecord создает скомпилированный класс с некоторыми неизменяемыми полями. это не правильные функции clojure (т.е. не класс, который реализует iFn). Если вы хотите вызвать его конструктор с помощью приложения (который ожидает iFun), вам нужно обернуть его в анонимную функцию, чтобы приложение могло его переварить.

(apply #(User. %1 %2 %3 %4) my-values)

это ближе к тому, с чего вы начали, хотя ваш подход к определению конструктора с хорошим описательным именем имеет свое очарование :)

из API:

Note that method bodies are
not closures, the local environment includes only the named fields,
and those fields can be accessed directy.

Написание собственной функции-конструктора, вероятно, является выходом из положения. Как сказал Артур Ульфельдт, у вас есть функция, которую вы можете использовать как функцию (например, с apply), а не вызов конструктора Java-interop.

С помощью собственной функции-конструктора вы также можете выполнять проверку аргументов или предоставлять аргументы по умолчанию. Вы получаете еще один уровень абстракции для работы; вы можете определить make-user для возврата хэш-карты для быстрой разработки, и если вы позже решите перейти на записи, вы можете сделать это, не нарушая всего. Вы можете писать конструкторы с несколькими элементами, или которые принимают аргументы с ключевыми словами, или делать множество других вещей.

(defn- default-user [name]
  (str (.toLowerCase name) "@example.com"))

(defn make-user
  ([name] (make-user name nil nil))
  ([name place] (make-user name nil place))
  ([name user place]
     (when-not name
       (throw (Exception. "Required argument `name` missing/empty.")))
     (let [user (or user (default-user name))]
       (User. name user place))))

(defn make-user-keyword-args [& {:keys [name user place]}]
  (make-user name user place))

(defn make-user-from-hashmap [args]
  (apply make-user (map args [:name :user :place])))

user> (apply make-user ["John" "[email protected]" "Somewhere"])
#:user.User{:name "John", :email "[email protected]", :place "Somewhere"}

user> (make-user "John")
#:user.User{:name "John", :email "[email protected]", :place nil}

user> (make-user-keyword-args :place "Somewhere" :name "John")
#:user.User{:name "John", :email "[email protected]", :place "Somewhere"}

user> (make-user-from-hashmap {:user "foo"})
; Evaluation aborted.
; java.lang.Exception: Required argument `name` missing/empty.

Одна простая вещь, которую вы можете сделать, это использовать деструктурирование.

(defn make-user [[name email place]]
  (User. name email place))

Тогда вы можете просто назвать это так

(make-user ["John" "[email protected]" "Dreamland"])

Обновление для Clojure 1.4

derecord теперь определяет ->User и map->User, следуя по стопам Горана, теперь можно

(defmacro instantiate [rec args] `(apply ~(symbol (str "->" rec)) ~args))

который также работает с небуквенными последовательностями, как в (instantiate User my-values). В качестве альтернативы, по аналогии с map->User можно определить функцию seq->User

(defmacro def-seq-> [rec] `(defn ~(symbol (str "seq->" rec)) [arg#] (apply ~(symbol (str "->" rec)) arg#)))

(def-seq-> User)

что позволит (seq->User my-values).