Отключить колесо мыши для QML Slider

Вы можете поместить MouseAreas на ползунки, чтобы украсть событие колеса мыши.

Что-то вроде этого:

import QtQuick 2.7
import QtQuick.Window 2.2
import QtQuick.Controls 1.4

ApplicationWindow {
    id: rootWindow

    visible: true
    width: 400
    height: 200
    title: qsTr("Hello World")

    ScrollView {
        id: _scrollview
        anchors.fill: parent
        flickableItem.flickableDirection: Flickable.VerticalFlick

        Column {
            Repeater {
                model: 40
                Slider {
                    width: rootWindow.width * 0.9
                    property int scrollValue: 10

                    MouseArea {
                            anchors.fill: parent
                            onWheel: {
                                //check if mouse is scrolling up or down
                                if (wheel.angleDelta.y<0){
                                    //make sure not to scroll too far
                                    if (!_scrollview.flickableItem.atYEnd)
                                            _scrollview.flickableItem.contentY += scrollValue
                                }
                                else {
                                    //make sure not to scroll too far
                                    if (!_scrollview.flickableItem.atYBeginning)
                                    _scrollview.flickableItem.contentY -= scrollValue
                                }
                            }
                            onPressed: {
                                // forward mouse event
                                mouse.accepted = false
                            }
                            onReleased: {
                                // forward mouse event
                                mouse.accepted = false
                            }
                    }
                }
            }
        }
    }
}

Использование события onWheel - для пересылки любой прокрутки к ScrollView. Другие события мыши, такие как щелчок, могут быть перенаправлены родителям (в данном случае ползункам), установив mouse.accepted = false; для любого события мыши, которое вы хотите переслать.

Изменить: Я только что увидел, что вам не нужно изменять содержимое ползунков. Вы также можете попробовать разместить MouseArea по всему ScrollView и проделать то же самое.

Самым простым, если это возможно для вас, было бы, вероятно, изменить с QtQuick.Controls 1.4, который можно рассматривать как устарел, не поддерживается или малоэффективный для нового QtQuick.Controls 2.0

В этой версии ваша проблема решена.
Чтобы удовлетворить вашу потребность в QtQuick.Controls 1.4, мы импортируем QtQuick.Controls 2.0 с псевдонимом:

import QtQuick 2.7
import QtQuick.Controls 1.4
import QtQuick.Controls 2.0 as NewCtrl

Column {
    Slider {
        id: oldslider // old slider from QtQuick.Controls 1.4 with your issue
        width: 500
        height: 250
    }

    NewCtrl.Slider {
        id: newsli // new slider without your issue. Both side by side
        width: 500
        height: 30
        wheelEnabled: false // use this to enable or disable the wheel
    }
}

Конечно, вы также можете использовать псевдоним для старых элементов управления и использовать новый в качестве основного ... Или использовать псевдоним и того, и другого. Как тебе нравится

Взлом с здесь сделал это за меня.

Slider {
    id: slider
    Component.onCompleted: {
        for (var i = 0; i < slider.children.length; ++i) {
            if (slider.children[i].hasOwnProperty("onVerticalWheelMoved") && slider.children[i].hasOwnProperty("onHorizontalWheelMoved")) {
                slider.children[i].destroy()
            }
        }
    }
}

Это может не работать с другими элементами управления (например, ComboBox).