Предикат Пролога (\=)/2 игнорируется

Проблема в приоритете оператора. Только в C/C#/Java/SQL и других процедурных языках в Прологе логическое ИЛИ (;) имеет другой приоритет, чем логическое И (',').

В большинстве процедурных языков такое выражение, как

A || B && C

Анализируется как

А || ( ДО НАШЕЙ ЭРЫ )

В Прологе выражение, подобное вашему

A ; B , C    

анализируется, как будто написано

A ; (B,C)

Так что ваши

likes(mike, X) :-
  man(X);
  woman(X),
  X \= mike.

по существу

likes(mike,X) :- man(X) ; ( woman(X) , X \= mike ) .

Вы утверждаете, что Майку нравятся все, кто

• мужчина (включая себя), ИЛИ
• женщина, которая не Майк.

Когда ты имеешь в виду, что Майк любит любого мужчину или женщину, кроме себя.

Итак... вам нужно сделать приоритет явным с помощью круглых скобок,

likes(A,B) :- ( man(B) ; woman(B) ) , A \= B .

или еще лучше, разбейте свой предикат на 2 предложения и сделайте его общим:

likes(A,B) :- man(B)   , A \= B .
likes(A,B) :- woman(B) , A \= B .

Улучшите ситуацию еще больше, сделав пол атрибутом объекта (человека), а не фактом сам по себе:

person( mike     , male ) .
person( danny    , male ) .
person( samuel   , male ) .
person( henry    , male ) .
person( samantha , female ) .
person( jane     , female ) .
person( betty    , female ) .
person( jenny    , female ) .

Тогда likes/2 еще проще, так как могут нравиться люди обоих полов:

likes(A,B) :- person(B,_) , A \= B .

Проблема связана с оператором ИЛИ (;):

man(mike).
man(danny).
man(samuel).
man(henry).
woman(samantha).
woman(jane).
woman(betty).
woman(jenny).

Ваше решение:

likes(mike, X) :- (man(X);woman(X)),X\=mike.

Другим решением (с использованием эквивалента оператора ИЛИ) может быть:

likes(mike, X) :- man(X), X\=mike.
likes(mike, X) :- woman(X).

Обратите внимание, что вам не нужен оператор ИЛИ.

Помимо проблемы ИЛИ есть еще одна проблема. Предикат (\=)/2 не является ограничением, что означает, что он не является полностью декларативным предикатом.

Предикат обычно запускается через отрицание как неудачу, а само отрицание как неудача не является полностью декларативным.

Предикат загружается из обычной унификации следующим образом:

X \= Y :- \+ X = Y.

Альтернативным определением может быть:

X \= X :- !, fail.
_ \= _.

Если вы действительно хотите иметь возможность обойти неравенство, вам следует взять систему Пролога с ограничениями, а затем прибегнуть к dif/2.

С dif/2 вы можете написать:

likes(mike, X) :-
    (dif(X, mike),
     man(X)
  ;  woman(X)).

Или следующее:

likes(mike, X) :-
    (man(X),
     dif(X, mike)
  ;  woman(X)).

И вы получите те же результаты. Это невозможно с (\=)/2.

Пока

P.S.: Причины проблем с (\=)/2. Отрицание как неудача \+ A иногда действует не только как ~A, но и как ~exists X1,..,Xn A. Заинтересованный читатель может захотеть просмотреть, по общему признанию, немного старое, но все еще применимое:

Теория доказательств логических программ с отрицанием
Роберт Штерк, Берн, 1992 г.
http://citeseerx.ist.psu.edu/viewdoc/download?doi=10.1.1.29.2745&rep=rep1&type=pdf