Шифрование и дешифрование сериализованного объекта

Первая часть кода заставляет меня задуматься, потому что (за пределами GoTo) похоже, что метод шифрования зависит от расширения файла. Поскольку пользователь может изменить это через Проводник, это очень хрупко. И не позволяйте пользователю выбирать: если нужно зашифровать, сделайте это; если нет, то не надо. Конечно, метод шифрования не должен зависеть от них (мы получаем большие деньги, чтобы принимать эти решения за них).

Шифрование с использованием BindingList(of Animal), которое мне оказалось под рукой:

Dim key As Byte()
Dim iv As Byte() = New Byte() {}

' see notes below
Using MD5 As New MD5CryptoServiceProvider
    ' UTF8 not unicode; convert password to Byte()
    Dim tmp = Encoding.UTF8.GetBytes(password & "$*^!#" & password)
    ' hash the PW to get the crypto Key
    key = MD5.ComputeHash(tmp)
    ' hash the Key to get the IV
    iv = MD5.ComputeHash(key)
End Using
    
Using rijAlg = Rijndael.Create()
      
    ' Create cryptor using the Key and IV
    Dim cryptor As ICryptoTransform = rijAlg.CreateEncryptor(key, IV)

    ' Open a filestream for the output file, wrap it with
    ' a CryptoStream created with the cryptor in WRITE (output) mode
    Using fs As New FileStream("C:\Temp\crypto.bin", FileMode.OpenOrCreate),
       cs As New CryptoStream(fs, cryptor, CryptoStreamMode.Write)

        ' serialize collection to CryptoStream (to disk)
        Dim bf As New BinaryFormatter
        bf.Serialize(cs, mcol)
    End Using

End Using

Для расшифровки используйте тот же ключ и IV:

mcol = Nothing

' the comments above pertain, just in reverse
Using rijAlg = Rijndael.Create()
    Dim cryptor As ICryptoTransform = rijAlg.CreateDecryptor(key, iv)
    Using fs As New FileStream("C:\Temp\crypto.bin", FileMode.Open),
       cs As New CryptoStream(fs, cryptor, CryptoStreamMode.Read)

        Dim bf As New BinaryFormatter
        ' Convert object to type
        mcol = CType(bf.Deserialize(cs), BindingList(Of Animal))
    End Using
End Using

' test:
For Each a As Animal In mcol
    Console.WriteLine(a.Name)
Next

Все мои животные пережили поездку:

Ровер
Гизмо
Зигги

Главное, кажется, что вы используете слишком много потоков. В вашем дешифраторе вы пытаетесь выполнить десериализацию из мемпотока, который не имеет ничего общего с криптопотоком, который читает файл. На самом деле это была просто созданная линия раньше. Криптопоток в основном просто обертывает любой реальный поток, который вы используете.

Кроме того, эта строка показывает, что вы не используете Option Strict:

photoJobs = formatter.Deserialize(memStreamSerial)

Deserialize возвращает объект, а photoJobs представляет собой своего рода коллекцию IIRC из прошлых сообщений. Обратите внимание, что мой код использует CType для преобразования в BindingList(Of Animal).

Используйте Option Strict для чего-то более сложного, чем «Hello, World». Всегда.

Крипто примечания / предостережения

Получение (хеширование) IV из пароля — плохая идея: это должны быть независимые фрагменты данных. IV должен быть уникальным для каждого фрагмента данных (чего не будет при повторном использовании PW) и уникальным. Я добавил некоторый произвольный текст в PW, чтобы хэш MD5 не был напрямую получен из PW, но он все еще неоптимален.

Во-вторых, MD5 устарел.

Чтобы создать случайный IV

Private Const MinSize = 7
Public Shared Function GetRandomBytes(size As Integer) As Byte()
    ' dont allow less than a sensible min
    Dim data(If(size < MinSize, MinSize, size)) As Byte

    Using rng As New RNGCryptoServiceProvider
        ' fill the array 
        rng.GetNonZeroBytes(data)
    End Using
    Return data

End Function

Поместите это в библиотеку криптоинструментов, потому что вы будете использовать ее для IV, а также соль для хэшей. Пример:

 myIV = CryptoUtils.GetRandomBytes(15)

Если IV каждый раз уникален, хитрость заключается в том, как сохранить его, чтобы одни и те же значения можно было использовать при расшифровке. IV не обязательно должен быть секретным, поэтому его можно сохранить в FileStream до того, как вы передадите его конструктору CryptoStream. Метод Decrypt делает обратное.

Их тоже можно преобразовать в методы, чтобы каждый раз использовался один и тот же процесс.

Наконец, ваши вопросы получат лучший отклик, если они будут более лаконичными. Ошибка явно указывает на проблему с криптографией, поэтому первые 2 блока являются более или менее шумными.