Indy, Access Violatio, когда слишком много подключений

можно ли уничтожить IdTCPServer по множеству подключений?

Вы задаете неправильный вопрос, потому что на самом деле вы не уничтожаете сам TIdTCPServer, вы просто закрываете бездействующие соединения из внешнего потока. Такая логика может (и должна) обрабатываться внутри события OnExecute вместо этого, где безопаснее всего получить доступ к соединению, например:

type
  PClient = ^TClient;
  TClient = record
    Activity_time: TDateTime;
    Heartbeat_time: TDateTime;
    AContext: TIdContext;
  end;

procedure TForm1.serverConnect(AContext: TIdContext);
var
  Client: PClient;
begin
  New(Client);
  Client^.Activity_time := Now();
  Client^.Heartbeat_time := Client^.Activity_time;
  AContext.Data := TObject(Client);
end;

procedure TForm1.serverDisconnect(AContext: TIdContext);
var
  Client: PClient;
begin
  Client := PClient(AContext.Data);
  AContext.Data := nil;
  if Client <> nil then Dispose(Client);
end;

procedure TForm1.serverExecute(AContext: TIdContext);
var
  Client: PClient;
  dtNow: TDateTime;
begin
  Client := PClient(AContext.Data);
  dtNow := Now();

  if SecondsBetween(dtNow, Client^.Activity_time) > 6 then
  begin
    AContext.Connection.Disconnect;
    Exit;
  end;

  if SecondsBetween(dtNow, Client^.Heartbeat_time) > 2 then
  begin
    AContext.Connection.IOHandler.WriteLn('E:');
    Client^.Heartbeat_time := dtNow;
  end;

  if AContext.Connection.IOHandler.InputBufferIsEmpty then
  begin
    if not AContext.Connection.IOHandler.CheckForDataOnSource(100) then
      Exit;
  end;

  // process incoming data as needed ...

  Client^.Activity_time := Now();
end;

Это простой способ отказаться от соединения, когда сервер занят (я думаю, что моя база данных не сложна (100 строк, только одна строка модифицируется одним соединением), но, может быть, это способ сохранить стабильность сервера?

Текущая архитектура не позволяет отказываться от принятия соединений. Вы можете разрешить серверу принимать соединения в обычном режиме, а затем закрывать принятые соединения, когда это необходимо. Вы можете сделать это в событии OnConnect или установить для свойства MaxConnection сервера низкое ненулевое число, чтобы позволить серверу автоматически отключать новые подключения, не тратя ресурсы на создание новых объектов TIdContext и потоков для них.

Другой вариант — вызвать метод StopListening() сервера, когда сервер занят, чтобы новые соединения больше не могли достичь сервера, а затем вызвать метод StartListening() сервера, когда вы снова будете готовы принимать новых клиентов. Существующие клиенты, которые уже подключены, не должны быть затронуты, хотя я еще не пробовал это сам.

Я знаю, что этот вопрос повторялся много раз, но я не нашел удовлетворительного ответа: как защитить приложение, чтобы избежать исключения сообщений: «Соединение закрыто изящно» и «Соединение сброшено узлом»?

Не следует их избегать. Пусть они случаются, это нормальные ошибки. Если они происходят внутри событий сервера, просто позвольте серверу нормально обрабатывать их для вас. Вот как TIdTCServer предназначен для использования. Если они происходят вне событий сервера, например, в вашем таймере, просто оберните операции сокета в блок try/except и двигайтесь дальше.